Contents
Dash IoT Guide (ESP32)
9 February 2024
This guide demonstrates how to make BLE, TCP and MQTT connections to an ESP32 IoT device using the Arduino or PlatformIO IDE and the DashIO Adruino library. It also shows how to load user controls (widgets) into your mobile device to monitor and control an IoT device.
The MQTT connection discussed in this guide is SSL/TLS enabled and we highly recommend that you only use SSL/TLS connections. The Dash MQTT server only accepts SSL connections.
Getting Started
For the big picture on Dash, take a look at our website: dashio.io
For the Dash arduino library: github.com/dashio-connect/arduino-dashio
Requirements
Grab an ESP32 board, Arduino IDE and follow this guide. The examples in this guide should work on ESP32 development boards available for the Arduino IDE.
You will need to install the Dash app on your mobile phone or tablet.
If you'd like to connect to your IoT devices through the Dash MQTT broker, setup an account on the dashio.io website.
Install
Dash
You will need to add the Dash library into your project. Download the Dash library from GitHub with the following link: https://github.com/dashio-connect/arduino-dashio
Place the Dash library files into your project directory or add them into your library.
ESP32 Support (WiFi, TCP and mDNS)
If you haven't yet installed the ESP32 Arduino IDE support from espressif, please check the following link for instructions: https://github.com/espressif/arduino-esp32#installation-instructions
From the ESP32 espressif library, we will use the secure WiFi client (WiFiClientSecure.h) to enable SSL connections, which are required for the dash server.
For mDNS, we are using the ESPmDNS library, which is included in the ESP32 espressif library.
The arduino-timer library is also used for the WiFi and MQTT connection and is available in the Arduino IDE Library Manager. Search the library manager for the library titled "arduino-timer" by Michael Contreras and install.
MQTT
For MQTT we are using the arduino-mqtt library created by Joël Gähwiler. This is available in the Arduino IDE Library Manager, by searching for "mqtt" and installing the library titled "MQTT" by Joël Gähwiler. This library is also stored on GitHub where there are examples and other useful information: https://github.com/256dpi/arduino-mqtt
BLE
We will use the ESP32 BLE Arduino library by h2zero, which is included in the Arduino IDE Library manager. Search the library manager for the library titled "NimBLE" and install.
PlatformIO
Using Dash with the PlatformIO IDE is easy.
- Install the Dash library into your project. The easiest way to do this is to download the arduino-dashio library into the lib directory of your project.
- Install the libraries listed above using the PlatformIO Libraries manager.
- Edit the platformio.ini file for you project by adding
lib_ldf_mode = deepto enable all the required files to be found and also addmonitor_speed = 115200to set the required serial monitor speed.
Your finished platformio.ini file should look something like this:
[env:esp32thing_plus]
platform = espressif32
board = esp32thing_plus
framework = arduino
lib_deps =
h2zero/NimBLE-Arduino@^1.4.1
contrem/arduino-timer@^2.3.1
256dpi/MQTT@^2.5.0
lib_ldf_mode = deep
monitor_speed = 115200Guide
BLE Basics
Lets start with a simple BLE connection.
#include "DashioESP.h"
DashDevice dashDevice("ESP32_Type");
DashBLE ble_con(&dashDevice, true);
void setup() {
Serial.begin(115200);
ble_con.begin();
dashDevice.setup(ble_con.macAddress(), "Joe Name"); // unique deviceID, and device name
}
void loop() {
ble_con.run();
}This is about the fewest number of lines of code necessary to get talking to the Dash app. There is a lot happening under the hood to make this work. After the #include "DashioESP.h" we create a device with the device_type as its only attribute. We also create a BLE connection, with the newly created device being an attribute to the connection. The second attribute of the BLE connection enables the received and transmitted messages to be printed to the serial monitor to make debugging easier.
In the setup() function we start the BLE connection with ble_conn.begin(). For BLE connections we start the connection before dashDevice.setup. This is to make sure we get a sensible value for the mac address, which is then supplied to the device as a unique device_ID.
We call the device setup function dashDevice.setup(ble_con.macAddress(), "Joe Name") with two parameters that describe the device to the Dash app to allow it uniquely identify and provide a name for each device.
This device is discoverable by the Dash app. You can also discover your IoT device using a third party BLE scanner (e.g. "BlueCap" or "nRF Connect"). The BLE advertised name of your IoT device will be a concatentation of "DashIO_" and the device_type.
Setup the Arduino IDE serial monitor to 115200 baud and run the above code. Then run the Dash app on your mobile device and you will see connection "WHO" messages on the Arduino serial monitor as the Dash app detects and communicates with your IoT device.
Troubleshooting:
Occasionally, the Dash app is unable to discover a BLE connection to the IoT device. If this occurs, try deleting the the IoT device from the Bluetooth Settings of your phone or tablet.
Lets add Dial control messages that are sent to the Dash app every second. To do this we create a new task to provide a 1 second time tick and then send a Dial value message from the loop every second.
#include "DashioESP.h"
DashDevice dashDevice("ESP32_Type");
DashBLE ble_con(&dashDevice, true);
bool oneSecond = false; // Set by timer every second.
void oneSecondTimerTask(void *parameters) {
for(;;) {
vTaskDelay(1000 / portTICK_PERIOD_MS);
oneSecond = true;
}
}
void setup() {
Serial.begin(115200);
ble_con.begin();
dashDevice.setup(ble_con.macAddress(), "Joe Name"); // unique deviceID, and device name
// Setup 1 second timer task
xTaskCreate(
oneSecondTimerTask,
"One Second",
1024, // stack size
NULL,
1, // priority
NULL // task handle
);
}
void loop() {
ble_con.run();
if (oneSecond) { // Tasks to occur every second
oneSecond = false;
ble_con.sendMessage(dashDevice.getDialMessage("D01", int(random(0, 100))));
}
}The line dashDevice.getDialMessage("D01", int(random(0, 100))) creates the message with two parameters. The first parameter is the control_ID which identifies the specific Dial control in the Dash app and the second parameter is simply the Dial value.
Once again, run the above code and the Dash app. This time, "DIAL" messages will be seen on the serial monitor every second.
The next step is to show the Dial values from the messages on a control on the Dash app.
In the Dash app, tap the 
All Devices button, followed by the 
Find New Device button. Then select the BLE Scan option to show a list of new IoT devices that are BLE enabled. Your IoT device should be shown in the list. Select your device and from the next menu select Create Device View. This will create an empty **Device View** for your new IoT deivce. You can now add controls to the Device View:
Adding Controls to Dash App
Once you have discovered your IoT device in the Dash app and have a Device View available for editing, you can add controls to the Device View:
- Start Editing: Tap the
Edit button (if not already in editing mode). - Add Dial Control: Tap the Add Control button and select the Dial control from the list.
- Edit Controls: Tap the Dial control to select it. The Control Settings Menu button will appear in the middle of the Control. The Control can then be dragged and resized (pinch). Tapping the button allows you to edit the Control settings where you can setup the style, colors and other characteristics of your Control. Make sure the Control_ID is set to the same value that is used in the Dial messages (in this case it should be set to "D01").
- Quit editing: Tap the Edit button again.
Edit button (if not already in editing mode).
Add Control button and select the Dial control from the list.
Control Settings Menu button will appear in the middle of the Control. The Control can then be dragged and resized (pinch). Tapping the 
Edit button again.The Dial on the Dash app will now show the random Dial values as they arrive.
The next piece of the puzzle to consider is how your IoT device can receive data from the Dash app. Lets add a Knob and connect it to the Dial.
In the Dash app you will need to add a Knob control onto your Device View, next to your Dial control. Edit the Knob to make sure the Control ID of the Knob matches what you have used in your Knob messages (in this case it should be "KB01"), then quit edit mode.
Continuing with the BLE example, in the Arduino code we need to respond to messages coming in from a Knob control that we just added to the Dash app. To make the changes to your IoT device we add a callback, processIncomingMessage, into the BLE connection with the setCallback function.
#include "DashioESP.h"
DashDevice dashDevice("ESP32_Type");
DashBLE ble_con(&dashDevice, true);
void processIncomingMessage(MessageData * messageData) {
switch (messageData->control) {
case knob:
if (messageData->idStr == "KB01") {
String message = dashDevice.getDialMessage("D01", (int)messageData->payloadStr.toFloat());
ble_con.sendMessage(message);
}
break;
}
}
void setup() {
Serial.begin(115200);
ble_con.setCallback(&processIncomingMessage);
ble_con.begin();
dashDevice.setup(ble_con.macAddress(), "Joe Name"); // unique deviceID, and device name
}
void loop() {
ble_con.run();
}We obtain the Knob value from the message data payload that we receive in the processIncomingMessage function. We then create a Dial message with the value from the Knob and send this back to the Dash app. Remember to remove the timer and the associated Dial ble_con.sendMessage from the loop() function.
When you adjust the Knob on the Dash app, a message with the Knob value is sent your IoT device, which returns the Knob value into the Dial control, which you will see on the Dash app.
Finally, we should respond to the STATUS message from the Dash app. STATUS messages allows the IoT device to send initial conditions for each control to the Dash app as soon as a connection becomes active. Once again, we do this from the processIncomingMessage function and our complete code looks like this:
#include "DashioESP.h"
DashDevice dashDevice("ESP32_Type");
DashBLE ble_con(&dashDevice, true);
int dialValue = 0;
void processStatus(ConnectionType connectionType) {
String message((char *)0);
message.reserve(1024);
message = dashDevice.getKnobMessage("KB01", dialValue);
message += dashDevice.getDialMessage("D01", dialValue);
ble_con.sendMessage(message);
}
void processIncomingMessage(MessageData * messageData) {
switch (messageData->control) {
case status:
processStatus(messageData->connectionType);
break;
case knob:
if (messageData->idStr == "KB01") {
dialValue = messageData->payloadStr.toFloat();
String message = dashDevice.getDialMessage("D01", dialValue);
ble_con.sendMessage(message);
}
break;
}
}
void setup() {
Serial.begin(115200);
ble_con.setCallback(&processIncomingMessage);
ble_con.begin();
dashDevice.setup(ble_con.macAddress(), "Joe Name"); // unique deviceID, and device name
}
void loop() {
ble_con.run();
}If you would like to use a secure (encrypted and bonded) BLE connection, simply add a 6 digit numeric passkey (greater than 0) as a parameter to the BLE begin, for example:
ble_con.begin(654321);The mobile device will then require you to enter the passkey when it first connects with BLE to the IoT device. Secure BLE connections on the ESP32 require significant resources and may not run simultaniously with other connections. For combining connections (e.g. BLE and MQTT), you should ideally include a push button on your IoT device to enable the user to switch to the BLE connection and the passkey should then be displayed on the IoT device for the user to enter on their mobile device.
TCP Basics
Lets have a look at a TCP connection. For this we also need WiFi so it is slightly more complicated than BLE.
#include "DashioESP.h"
char WIFI_SSID[] = "yourWiFiSSID";
char WIFI_PASSWORD[] = "yourWiFiPassword";
DashDevice dashDevice("ESP32_Type");
DashTCP tcp_con(&dashDevice, true);
DashWiFi wifi;
void setup() {
Serial.begin(115200);
delay(1000);
dashDevice.setup(wifi.macAddress(), "Joe Name"); // unique deviceID, and device name
wifi.attachConnection(&tcp_con);
wifi.begin(WIFI_SSID, WIFI_PASSWORD);
}
void loop() {
wifi.run();
}Similar to the BLE example above, we create a device and a TCP connection with DashTCP tcp_con(&dashDevice, true); , with the device being an attribute to the connection. The second attribute of the TCP connection enables the received and transmitted messages to be printed to the serial monitor to make debugging easier.
By default, TCP port 5650 is used and only one TCP client can connect at a time. These values can be changed when initialising the TCP connection as follows:
DashTCP tcp_con(&dashDevice, true, 5650, 5);The third attribute specifies the port (5650 in this example) and the fourth is the number of TCP clients allowed (5 in this case). Increasing the number of TCP clients affects memory usage and the maximum value will depend on the capabilities of the processor you are using and how much memory your code uses.
In the setup() function we call the device setup with dashDevice.setup(wifi.macAddress(), "Joe Name"); The two parameters describe the device to the Dash app to allow it uniquely identify each device. The wifi object supplies the mac to the device, to be used as a unique device_ID.
We then attach the TCP connection to the wifi with wifi.attachConnection(&;tcp_con); This enables the wifi object to manage the TCP connection from here on in.
We start the WiFi wifi.begin(WIFI_SSID, WIFI_PASSWORD); with the WiFi SSID and password. This starts the wifi and TCP connection and sets up the the mDNS (also called Bonjour or Zeroconf) to make the device discoverable on the Dash app.
wifi.run(); is used to regularly check that the WiFi is connected and manage the attached connection.
This device is discoverable by the Dash app. You can also discover your IoT device using a third party Bonjour/Zeroconf discovery tool. The mDNS service will be "_DashIO._tcp." and individual IoT devices on this service are identified by their mac address (device_ID).
In the code above, make sure you replace yourWiFiSSID with your WiFi SSID and yourWiFiPassword with your WiFI password. Setup the Arduino IDE serial monitor with 115200 baud and run the code. You will see messages on the Arduino serial monitor, and after a few attempts, your IoT device should connect to your WiFi and start the mDNS service. Then run the Dash app on your mobile device and you will see connection "WHO" messages on the Arduino serial monitor.
Message processing for a TCP connection is done exactly the same way as for the BLE connection, by adding the processIncomingMessage callback into the TCP connection during setup function. Our finished code, with Dial and Knob added is:
#include "DashioESP.h"
char WIFI_SSID[] = "KotukluBlue";
char WIFI_PASSWORD[] = "yourWiFiPassword";
DashDevice dashDevice("ESP32_Type");
DashTCP tcp_con(&dashDevice, true);
DashWiFi wifi;
int dialValue = 0;
void processStatus(ConnectionType connectionType) {
String message((char *)0);
message.reserve(1024);
message = dashDevice.getKnobMessage("KB01", dialValue);
message += dashDevice.getDialMessage("D01", dialValue);
tcp_con.sendMessage(message);
}
void processIncomingMessage(MessageData *messageData) {
switch (messageData->control) {
case status:
processStatus(messageData->connectionType);
break;
case knob:
if (messageData->idStr == "KB01") {
dialValue = messageData->payloadStr.toFloat();
String message = dashDevice.getDialMessage("D01", dialValue);
tcp_con.sendMessage(message);
}
break;
}
}
void setup() {
Serial.begin(115200);
delay(1000);
tcp_con.setCallback(&processIncomingMessage);
dashDevice.setup(wifi.macAddress(), "Joe Name"); // unique deviceID, and device name
wifi.attachConnection(&tcp_con);
wifi.begin(WIFI_SSID, WIFI_PASSWORD);
}
void loop() {
wifi.run();
}Run the Dash app once more. Tap the All Devices button, followed by the Find New Device button. Then select the TCP Discovery option to show a list of new IoT devices that are mDNS enabled. Your device will be shown (named "Joe Name"). Select your IoT device.
Troubleshooting: The mac that is provided by the WiFi peripheral in the ESP32 is not the same as the mac provided by the BLE peripheral. Therefore, when you select your new TCP connection it will create a new Device. You will need to edit the Device View that you created in the BLE example to be associated with your new device.
For the next step, you will need to setup your Dash app with Dial and Knob controls, as described in the section above Adding Controls to Dash App.
When you adjust the Knob on the Dash app, a message with the Knob value is sent your IoT device, which returns the Knob value into the Dial control, which you will see on the Dash app.
MQTT Basics
Lastly, lets look at a MQTT connection. We also need the WiFi for MQTT.
#include "DashioESP.h"
// WiFi
char WIFI_SSID[] = "yourWiFiSSID";
char WIFI_PASSWORD[] = "yourWiFiPassword";
// MQTT
char MQTT_USER[] = "yourMQTTuserName";
char MQTT_PASSWORD[] = "yourMQTTpassword";
DashDevice dashDevice("ESP32_Type");
DashMQTT mqtt_con(&dashDevice, true, true);
DashWiFi wifi;
void setup() {
Serial.begin(115200);
dashDevice.setup(wifi.macAddress(), "Joe Name"); // unique deviceID, and device name
mqtt_con.setup(MQTT_USER, MQTT_PASSWORD);
wifi.attachConnection(&mqtt_con);
wifi.begin(WIFI_SSID, WIFI_PASSWORD);
}
void loop() {
wifi.run();
}Once again we create a device and this time a MQTT connection, with the device being an attribute to the connection. The second attribute of the MQTT connection enables a push notification to be sent to your mobile phone when the IoT device reboots (dash MQTT broker only). The final attribute enables the received and transmitted messages to be printed to the serial monitor for easy debugging.
In the setup() function we setup the device with two parameters. These parameters describe the device to the Dash app to allow it uniquely identify each device. The wifi object supplies the mac address to the device, to be used as a unique device_ID.
For MQTT connections, the device must be setup before we begin the wifi.
The MQTT connection setup requires the MQTT broker username and password, supplied in the mqtt_con.setup(MQTT_USER, MQTT_PASSWORD); method.
We then attach the MQTT connection to the wifi with wifi.attachConnection(&mqtt_con);. This enables to wifi object to manage the MQTT connection from here on in.
Finally, we start the WiFi with wifi.begin(WIFI_SSID, WIFI_PASSWORD);, including parameters for the SSID and password.
wifi.run(); is used to regularly check that the WiFi is connected and to manage the attached connection.
This device is discoverable by the Dash app.
In the code above, make sure you replace yourWiFiSSID with your WiFi SSID, yourWiFiPassword with your WiFI password, yourMQTTuserName with you dash account username and yourMQTTpassword with your dash account password. Setup the Arduino IDE serial monitor with 115200 baud and run the code. You will see messages on the Arduino serial monitor, and after a few attempts, your IoT device should connect to your WiFi and then connect to the dash MQTT server.
Message processing for a MQTT connection is done exactly the same way as for the BLE connection, by adding the processIncomingMessage callback into the MQTT connection during the setup() function. Our finished code, with Dial and Knob added is:
#include "DashioESP.h"
// WiFi
char WIFI_SSID[] = "yourWiFiSSID";
char WIFI_PASSWORD[] = "yourWiFiPassword";
// MQTT
char MQTT_USER[] = "yourMQTTuserName";
char MQTT_PASSWORD[] = "yourMQTTpassword";
DashDevice dashDevice("ESP32_Type");
DashMQTT mqtt_con(&dashDevice, true, true);
DashWiFi wifi;
int dialValue = 0;
void processStatus(ConnectionType connectionType) {
String message((char *)0);
message.reserve(1024);
message = dashDevice.getKnobMessage("KB01", dialValue);
message += dashDevice.getDialMessage("D01", dialValue);
mqtt_con.sendMessage(message);
}
void processIncomingMessage(MessageData *messageData) {
switch (messageData->control) {
case status:
processStatus(messageData->connectionType);
break;
case knob:
if (messageData->idStr == "KB01") {
dialValue = messageData->payloadStr.toFloat();
String message = dashDevice.getDialMessage("D01", dialValue);
mqtt_con.sendMessage(message);
}
break;
}
}
void setup() {
Serial.begin(115200);
dashDevice.setup(wifi.macAddress(), "Joe Name"); // unique deviceID, and device name
mqtt_con.setup(MQTT_USER, MQTT_PASSWORD);
mqtt_con.setCallback(&processIncomingMessage);
wifi.attachConnection(&mqtt_con);
wifi.begin(WIFI_SSID, WIFI_PASSWORD);
}
void loop() {
wifi.run();
}Run the Dash app once more. Tap the All Devices button, followed by the Find New Devices button. Then select the My Devices On Dash option to show a list of new IoT devices that have announced themselves to the dash server. Your device will be shown (named "Joe Name"). Select your IoT device to add the MQTT connection to your existing IoT device with the TCP connection.
For the next step, you will need to setup your Dash app with Dial and Knob controls, as described in the section above Adding Controls to Dash App.
When you adjust the Knob on the Dash app, a message with the Knob value is sent your IoT device, which returns the Knob value into the Dial control, which you will see on the Dash app.
For MQTT connections operating through the dash MQTT broker, a service is available for sending alarms (push notifications) to your mobile device. These are handy for sending messages or alarms to the user when they are not currently using the Dash app. To send an alarm, simply call the sendMessage method with two attrbutes; the first being any message String and the second having alarm_topic specified.
mqtt_con.sendMessage("message", alarm_topic);Combining BLE, TCP and MQTT
The ESP32 is capable of operating with any two of the three connection types at the same time. It just desn't have enough jibbers to run all three together. It's relativelty easy to combine the code for two connections in one ESP32 IoT device where each connection calls a common processIncomingMessage callback.
However, BLE connections consume large amounts of resources and significantly slow down the connections on ESP32. Therefore, it is recommended that the ESP32 is setup to switch between BLE and other connections. This may be done with a physical switch or other methods. It is best to use BLE for provisioning and then switch to a more secure protocol (TCP or MQTT).
Note that the wifi mac address is not identical to the BLE mac addresss. Therefore, if you are combining connections, it is best to stick with the wifi mac address for your device_ID.
When combining connections, it is useful to create a generic sendMessage function to reply to an incoming message for a specific connection type. This prevents sending unnecessary reply messages to all connections:
void sendMessage(ConnectionType connectionType, const String& message) {
if (connectionType == TCP_CONN) {
tcp_con.sendMessage(message);
} else if (connectionType == BLE_CONN) {
ble_con.sendMessage(message);
} else {
mqtt_con.sendMessage(message);
}
}This is just the beginning and there is a lot more we can do. Take a look at the examples in the library to see more details.
Layout Configuration
Layout configuration allows the IoT device to hold a copy of the complete layout of the device as it should appear on the Dash app. It includes all infomration for the device, controls (size, colour, style etc.), device views and connections.
When the Dash app discovers a new IoT device, it will download the Layout Configuration from the IoT device to display the device controls they way they have been designed by the developer. This is particularly useful developing commercial products and distributing your IoT devices to other users.
To include the Layout Configuration in your IoT device, simply follow these steps:
- Design your layout in the Dash app and include all controls and connections that you need in your layout.
- Export the layout: Tap on the Device button, then tap the Export Layout button.
- Select the provisioning setup that you want (see below for provisioning details) and tap the Export button. The Layout Configuration will be emailed to you.
- Copy and paste the C64 configuration text from the email into your Arduino code, assigning it to a pointer to store the text in program memory. Your C64 configuration text will be different to that shown below.
- Add the pointer to the C64 configuration text (configC64Str) as a second attribute to the DashDevice object.
- Add the Layout Config Revision integer (CONFIG_REV) as a third attribute to the DashDevice object.
const char configC64Str[] PROGMEM =
"lVNNb9swDP0rhQ47CUPiLM2WW2S7bhEndh3V3TAMgxursRZH8mQ5Hy3y30f5I83W7lD4QpOPpPge+Yx84qPx9x8YTecBAesZVRVP"
"0RhNh2RbrarLW5HE9zNvE4ZeFa8QRqU+5AwA8yCaTXxwLKXQSuY3jskivb7BMJEGIj8EImI5S0rAa1UxjDbJHo37vR5GRaKY0HWS"
"E9dJiqVxkleAHUFcc123mQr5AMGM8VWmo0Rzica9j9ZliwhlycEnAEmD0LTO5G7Gxcw0anoeOswpe/gJviFGa6hty1wq8wjGiouQ"
"izXUSHmSX8k8l7uybt8WMu4O/o2ZMGB3PNXZWWWM9q/6WdbIGg1geg7v7B2B7YXvRA3v1P1KG8u5aV2zSdga7vyusfzAa4xJ7DTG"
"wrdpi7f91nDi+L7WsNOIBJHjRgsjklY5cHIFWi34E8QGwPFK8RQGqjaiRGPLMuSBKo2nG1pUmxOk/7fYrW6mNJEqZaoj5z7jmnWR"
"9UqkXYAYeRv/f7FUJaKst2N5ALZMyy45WRp1us1wQI6LDxftgph8aiJE7t9o14VeVTccRCA0MDI4g74Q1f+MEYex58nGdL0r0LEW"
"a+Kfn8uXXqx+E3JNPe/GyTLuFtNf+9uzcyGTCP4KxZa8rPd18A+ZNZfvvw/Dwnvuo95tnp/49xRjAr11Jf2h+eAlkgv9Iu5p82Ez"
"Hpg6a2C7c+pGb97ge66kElyDHAidH4x9HbVnQr0ovG5MQum8s7z2ZuwruJRnlLItX7IF01UBpQRoh3f8kWO9LH4WUmmcJmWGZ7eU"
"YuK7mNphM5FT58Wc7dp9f1xFbAvm8fgH";
DashDevice dashDevice(DEVICE_TYPE, configC64Str, CONFIG_REV);Here is our Knob and Dial example, with BLE, TCP and MQTT connections and Layout Configuration added:
#include "DashioESP.h"
const char configC64Str[] PROGMEM =
"lVNNb9swDP0rhQ47CUPiLM2WW2S7bhEndh3V3TAMgxursRZH8mQ5Hy3y30f5I83W7lD4QpOPpPge+Yx84qPx9x8YTecBAesZVRVP"
"0RhNh2RbrarLW5HE9zNvE4ZeFa8QRqU+5AwA8yCaTXxwLKXQSuY3jskivb7BMJEGIj8EImI5S0rAa1UxjDbJHo37vR5GRaKY0HWS"
"E9dJiqVxkleAHUFcc123mQr5AMGM8VWmo0Rzica9j9ZliwhlycEnAEmD0LTO5G7Gxcw0anoeOswpe/gJviFGa6hty1wq8wjGiouQ"
"izXUSHmSX8k8l7uybt8WMu4O/o2ZMGB3PNXZWWWM9q/6WdbIGg1geg7v7B2B7YXvRA3v1P1KG8u5aV2zSdga7vyusfzAa4xJ7DTG"
"wrdpi7f91nDi+L7WsNOIBJHjRgsjklY5cHIFWi34E8QGwPFK8RQGqjaiRGPLMuSBKo2nG1pUmxOk/7fYrW6mNJEqZaoj5z7jmnWR"
"9UqkXYAYeRv/f7FUJaKst2N5ALZMyy45WRp1us1wQI6LDxftgph8aiJE7t9o14VeVTccRCA0MDI4g74Q1f+MEYex58nGdL0r0LEW"
"a+Kfn8uXXqx+E3JNPe/GyTLuFtNf+9uzcyGTCP4KxZa8rPd18A+ZNZfvvw/Dwnvuo95tnp/49xRjAr11Jf2h+eAlkgv9Iu5p82Ez"
"Hpg6a2C7c+pGb97ge66kElyDHAidH4x9HbVnQr0ovG5MQum8s7z2ZuwruJRnlLItX7IF01UBpQRoh3f8kWO9LH4WUmmcJmWGZ7eU"
"YuK7mNphM5FT58Wc7dp9f1xFbAvm8fgH";
char WIFI_SSID[] = "yourWiFiSSID";
char WIFI_PASSWORD[] = "yourWiFiPassword";
char MQTT_USER[] = "yourMQTTuserName";
char MQTT_PASSWORD[] = "yourMQTTpassword";
DashDevice dashDevice("ESP32_Type", configC64Str, 1);
DashBLE ble_con(&dashDevice, true);
DashTCP tcp_con(&dashDevice, true);
DashMQTT mqtt_con(&dashDevice, true, true);
DashWiFi wifi;
int dialValue = 0;
void sendMessage(ConnectionType connectionType, const String& message) {
if (connectionType == TCP_CONN) {
tcp_con.sendMessage(message);
} else if (connectionType == BLE_CONN) {
ble_con.sendMessage(message);
} else {
mqtt_con.sendMessage(message);
}
}
void processStatus(ConnectionType connectionType) {
String message((char *)0);
message.reserve(1024);
message = dashDevice.getKnobMessage("KB01", dialValue);
message += dashDevice.getDialMessage("D01", dialValue);
sendMessage(connectionType, message);
}
void processIncomingMessage(MessageData *messageData) {
switch (messageData->control) {
case status:
processStatus(messageData->connectionType);
break;
case knob:
if (messageData->idStr == "KB01") {
dialValue = messageData->payloadStr.toFloat();
String message = dashDevice.getDialMessage("D01", dialValue);
sendMessage(messageData->connectionType, message);
}
break;
}
}
void setup() {
Serial.begin(115200);
delay(1000);
dashDevice.setup(wifi.macAddress(), "Joe Name"); // unique deviceID, and device name
tcp_con.setCallback(&processIncomingMessage);
wifi.attachConnection(&tcp_con);
mqtt_con.setup(MQTT_USER, MQTT_PASSWORD);
mqtt_con.setCallback(&processIncomingMessage);
wifi.attachConnection(&mqtt_con);
wifi.begin(WIFI_SSID, WIFI_PASSWORD);
ble_con.setCallback(&processIncomingMessage);
ble_con.begin();
}
void loop() {
wifi.run();
ble_con.run();
}Provisioning (Commissioning)
Provisioning is the method by which the Dash app can send user credentials and other setup information to the IoT device and the IoT device will store this data in non-volatile memory.
Details of the provisioning functionality available in an IoT device are contained in the Layout Configuration and must be setup when exporting the Layout Configuration from the Dash app.
A provisioning library is available within the Dash library for the ESP32 (DashioProvisionESP.h and DashioProvisionESP.cpp) which stores the following provisioning data to non-volatile memory:
- Device Name
- WiFi SSID
- WiFI Password
- Dash MQTT broker User Name
- Dash MQTT broker Password
The library exposes the following structure to contain the provisioning data:
struct DeviceData {
char deviceName[32];
char wifiSSID[32];
char wifiPassword[63];
char dashUserName[32];
char dashPassword[32];
char saved;
};Use the provisioning library as follows:
Include the library
#include "DashioProvisionESP.h";Create a provisioning object
DashProvision dashProvision(&dashDevice);Setup provisioning in the setup() function. For the TCP connection, we assign the provisioning information to the WiFi object or, for an MQTT connection, we assign the provisioning information to the WiFI object and MQTT connection object:
// setup
DeviceData defaultDeviceData = {DEVICE_NAME, WIFI_SSID, WIFI_PASSWORD, MQTT_USER, MQTT_PASSWORD};
dashProvision.load(&defaultDeviceData, &onProvisionCallback);
dashDevice.setup(wifi.macAddress());
mqtt_con.setup(dashProvision.dashUserName, dashProvision.dashPassword);
mqtt_con.setCallback(&processIncomingMessage);
wifi.attachConnection(&mqtt_con);
wifi.begin(dashProvision.wifiSSID, dashProvision.wifiPassword);Here we update the provisioning object with the default provisioning data (using the DeviceData structure), then load the provisioning data. If the provisioning data has never been saved, then the the default provisionig data will be used. We also include a provision callback (discussed later).
Add provisioning process message in the processIncomingMessage callback from the example above becomes:
void processIncomingMessage(MessageData * messageData) {
switch (messageData->control) {
case status:
processStatus(messageData->connectionType);
break;
case knob:
if (messageData->idStr == "KB01") {
dialValue = messageData->payloadStr.toFloat();
String message = dashDevice.getDialMessage("D01", dialValue);
sendMessage(messageData->connectionType, message);
}
break;
default:
dashProvision.processMessage(messageData);
break;
}
}Your IoT device will let the Dash app know what provisioning services are available when it down loads the layout configuration.
And finally, here is the onProvisionCallback:
void onProvisionCallback(ConnectionType connectionType, const String& message, bool commsChanged) {
sendMessage(connectionType, message);
if (commsChanged) {
mqtt_con.setup(dashProvision.dashUserName, dashProvision.dashPassword);
wifi.begin(dashProvision.wifiSSID, dashProvision.wifiPassword);
} else { // Must be a name change
mqtt_con.sendWhoAnnounce(); // Update to announce topic with new name
}
}mqtt_con.setup to update the MQTT connection with the new username and password and wifi.begin to update wifi with the new SSID and password. Alternatively, you could reboot the processor for a fresh start which would also update the MQTT connection and WiFi credentials.
To provision your device, run the Dash app and tap the All Devices button and select your device. Tap the 
Provisioning button and follow the instructions.
The final provisioning feature is the ability to "Reset" your IoT device. The Dash app provisioning menu also includes a "Reset Device" button. In your IoT device, you will receive an incoming message of ControlType = resetDevice which you can manage in your processIncomingMessage callback as shown in the following example:
void processIncomingMessage(MessageData * messageData) {
switch (messageData->control) {
case status:
processStatus(messageData->connectionType);
break;
case knob:
if (messageData->idStr == "KB01") {
dialValue = messageData->payloadStr.toFloat();
String message = dashDevice.getDialMessage(D01, dialValue);
sendMessage(messageData->connectionType, message);
}
break;
case resetDevice:
sendMessage(messageData->connectionType, dashDevice.getResetDeviceMessage());
delay(2000); // Make sure the above message is sent before resetting
ESP.restart();
break;
default:
dashProvision.processMessage(messageData);
break;
}
}Jump In and Build Your Own IoT Device
When you are ready to create your own IoT device, the Dash Arduino C++ Library will provide you with more details about what you need to know: